;
;    Andy Pevy AT90S1200 AVR 9k6 G4XYW modem code
;    Copyright (C) 1999  Andy Pevy 
;    REGEN code Copyright (C) 2000 Robin Gilks
;
;    This program is free software; you can redistribute it and/or modify
;    it under the terms of the GNU General Public License as published by
;    the Free Software Foundation; either version 2 of the License, or
;    (at your option) any later version.
;
;    This program is distributed in the hope that it will be useful,
;    but WITHOUT ANY WARRANTY; without even the implied warranty of
;    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;    GNU General Public License for more details.
;
;    You should have received a copy of the GNU General Public License
;    along with this program; if not, write to the Free Software
;    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
;
;       V0.01   27-May-2000
;
;	andy@g4xyw.demon.co.uk
;	g4xyw@g4xyw.ampr.org
;	g8ecj@abmdata.demon.co.uk
;	g8ecj@gb7ipd.ampr.org
;
; History
;       0.00 - Hacked out from the modem code
;       0.01 - added options to disable CWID, invert it & invert clock
;
;==========================================================
;
;       This code performs the function of a regenerative repeater
;       in conjunction with a full duplex G4XYW 9k6 modem
;
;       It uses the Atmel AT90S1200 CPU clocked at 9.8304Mhz
;
;       The DCD line at pin PB7 is monitored for activity. When
;       it indicates a signal, the PTT output line at pin PB4 is
;       activated. The Transmit data line at pin PB 3 has HDLC flags sent
;       on it to indicate a busy condition.
;
;       The Receive data is presented at pin PB2. It is then
;       analyzed to extract a clock from it.
;       The data is checked for valid start of frame sequence (HDLC
;       flag) and once seen, data is copied across to the Transmit data
;       line. On seeing bad data, the system reverts to sending flags.
;
;       CW ident is also available.  The values are programmed directly
;       into the EEPROM at startup.
;
;       The hardware for this software is compatible with the modem itself
;       (ie. it can be run on a depopulated modem board with no analogue
;       circuitry fitted). The PTT/DCD and TX/RX connections on the 9 pin
;       connector are swapped and thats it!!
;
;       To operate the regen at other than 9600bps the define 'BAUD' is
;       changed in the user definable section below. This would work
;       with a Baycom board for example!!
;
;==========================================================
;
;	Pin definition:-
;
;	Pin	1	~RESET		(pulled up internally)
;               2       PD0             OPTION_0
;               3       PD1             OPTION_1
;		4	XTAL2 (out)
;		5	XTAL1 (in)      9.8304Mhz
;               6       PD2             OPTION_2
;               7       PD3             OPTION_3
;               8       PD4/T0          OPTION_4
;               9       PD5             OPTION_5
;		10	0v
;		11	PD6		~Read_options	
;               12      PB0             Spare
;               13      PB1             Spare
;               14      PB2             RXin            (HDLC in NRZI form)
;               15      PB3             TXout           (HDLC in NRZI form)
;               16      PB4             LEDout\
;               17      PB5 (MOSI)      PTTout
;               18      PB6 (MISO)      RXclock
;               19      PB7 (SCK)       DCDin
;		20	Vcc
;
;=================================================================
;

.DEVICE AT90S1200
;;
.NOLIST
.INCLUDE "1200def.inc"
.LIST
;;
;============================================================
; morse lookup values that get put directly into EEPROM at startup
;============================================================
;0b111111       ; 0     -----   Zero
;0b111110       ; 1     .----   One
;0b111100       ; 2     ..---   Two
;0b111000       ; 3     ...--   Three
;0b110000       ; 4     ....-   Four
;0b100000       ; 5     .....   Five
;0b100001       ; 6     -....   Six
;0b100011       ; 7     --...   Seven
;0b100111       ; 8     ---..   Eight
;0b101111       ; 9     ----.   Nine
;0b000110       ; A     .-      Alpha
;0b010001       ; B     -...    Bravo
;0b010101       ; C     -.-.    Charlie
;0b001001       ; D     -..     Delta
;0b000010       ; E     .       Echo
;0b010100       ; F     ..-.    Foxtrot
;0b001011       ; G     --.     Golf
;0b010000       ; H     ....    Hotel
;0b000100       ; I     ..      India
;0b011110       ; J     .---    Juliet
;0b001101       ; K     -.-     Kilo
;0b010010       ; L     .-..    Lima
;0b000111       ; M     --      Mike
;0b000101       ; N     -.      November
;0b001111       ; O     ---     Oscar
;0b010110       ; P     .--.    Papa
;0b011011       ; Q     --.-    Quebec
;0b001010       ; R     .-.     Romeo
;0b001000       ; S     ...     Sierra
;0b000011       ; T     -       Tango
;0b001100       ; U     ..-     Uniform
;0b011000       ; V     ...-    Victor
;0b001110       ; W     .--     Whiskey
;0b011001       ; X     -..-    X-ray
;0b011101       ; Y     -.--    Yankee
;0b010011       ; Z     --..    Zulu
;0xff           ; space
;0              ; terminator
;============================================================

.equ    BIT0    =       0
.equ	BIT1	=	1
.equ	BIT2	=	2
.equ	BIT3	=	3
.equ	BIT4	=	4
.equ	BIT5	=	5
.equ	BIT6	=	6
.equ	BIT7	=	7
;;
;=================================================================
;;
.equ    FLAG_DATA       = 0x7e          ; what a HDLC flag looks like
.equ    CLOCK           = 9830400       ; am I really running this fast?

.def    millisec        = r0            ; count millisecs
.def    ticks           = r1            ; count 10mS
.def    seconds         = r2            ; count seconds
.def    ten_secs        = r3            ; count tens of seconds
.def    ditclock        = r4            ; count dit time in ticks
;;
.def	irq_temp	= r5		; saved temp
.def	irq_sreg	= r6		; saved SREG
;
.def    txdat           = r7            ; what to send out
;
.def	options		= r8		; option pins
;;
;	option bits
;
.equ	NOCWID		= BIT0		; cwid disabled
.equ    INVCWID         = BIT1          ; invert the mark/space of the CWID
.equ    INVRXC          = BIT2          ; invert RX clock (not used but handy!!)
.equ    INVDCD          = BIT3          ; invert DCD sense
.equ    ALLXFER         = BIT4          ; always transfer - don't flag!!
.equ    SPARE4          = BIT5          ;
.equ    TEST_MODE       = BIT7          ; set if both DCD lines tied together
;;
.def    pblast          = r9            ;
;;
.def    temp            = r16           ; scratch location.
.def	pbnow		= r17		; used to detect TXin changing.
.def    counter         = r18           ;
.def	txpll		= r19		; Locks to incoming HDLC
.def	action		= r20           ; action required
;;
;	action bits
;
.equ	SAMPLE		= BIT0		; sample data now
.equ    CWID_SEND       = BIT1          ; time to CWID
.equ    CWID_DIT        = BIT2          ; one dits worth time gone by
.equ    XFER_FLAG       = BIT3          ; if copying RX data to TX
;;
.def    temp1           = r21
.def    delay           = r22
.def    flag_reg        = r23           ; flag data
.def    cw_interval     = r25           ; index into cosine lookup table.
.def    raw_rx          = r26           ; raw incoming rx data
.def    rxdat           = r27           ; incoming rx data NRZI decoded

.def    cwid_dat        = r28           ; cwid bit data
.def    reload          = r29           ; adjusted TCNT0 reload value
;;
;
;	PortB pin definitions.
;
.equ    RXin            = PB2           ; bit 2 on PORTB
.equ    TXout           = PB3           ; bit 3 on PORTB
.equ    LEDout          = PB4           ; bit 4 on PORTB
.equ    PTTout          = PB5           ; bit 5 on PORTB
.equ    RXclock         = PB6           ; bit 6 on PORTB
.equ    DCDin           = PB7           ; bit 7 on PORTB
;;
.macro  set_ee
        ldi temp,@0
        rcall write_ee
.endmacro

.CSEG
.ORG 0
;;
;	Vectors live here..
;
	rjmp reset
	rjmp reset
	rjmp TIMER_int
;
reset:
;
;	Called at power on/master reset.
; write the EEPROM contents with the CWID

        ldi temp,0
        out EEAR,temp                   ; set up first eeprom address

;==================================================================
;%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
; This is where you customize the timings and CWID callsign
.equ    BAUD=9600               ; baud rate
.equ    CWID_TIME=1740          ; seconds between idents (10S granularity)
.equ    CWID_WPM=20             ; words per minute

; store CWID callsign where the code can access it easily
; select the relevant codes from the table above

        set_ee  0b001011       ; G     --.     Golf
        set_ee  0b010001       ; B     -...    Bravo
        set_ee  0b100011       ; 7     --...   Seven
        set_ee  0b001110       ; W     .--     Whiskey
        set_ee  0b001001       ; D     -..     Delta

        set_ee  0              ; terminator

;%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
;==================================================================

.equ    TX_RELOAD=CLOCK/64/BAUD ; clock / 8 / baud / 8

; PB4 has the LED on it!!
        ldi temp,0b00110000             ; bits 4 & 5 as output
        out DDRB,temp                   ; set up port B DDR.
        ldi counter,3
flash:
; three flashes of the LED - just like a KISS mode TNC!!! holding PTT off
        ldi temp,0b00000000
        out PORTB,temp                  ; set LEDout low, light LED
        rcall delay_5s
        ldi temp,0b00010000
        out PORTB,temp                  ; set LEDout high, LED off
        rcall delay_5s
        dec counter
        brne flash

;
; PTTout,DCDin,LEDout,RXin,TXout on Port B in bits 7-2
        ldi temp,0b01111000             ; PTT,LEDout,RXclock,TXout as outputs
        out DDRB,temp                   ; set up port B DDR.
;
        ldi temp,0b01000000             ; 0x40
	out DDRD,temp			; and port D DDR.
;
	ldi temp,0b00111111		; Set PORTD6 = 0 and
	out PORTD,temp			; enable pullups on port D
;
	ldi temp,0xFF			; Wait a little
delay:	dec temp			; to allow the hardware
	brne delay			; to settle
;
	in temp,PIND			; read port D
	com temp			; invert it.
        andi temp,0b00111111            ; 6 bits only
        mov options,temp                ; and save it.
;
        ldi temp,0b01000000             ; make PORTD6 = 1.
        out PORTD,temp
;
	ldi temp,0b01111111		; 0x7F
	out DDRD,temp			; and port D DDR.
;
	clr temp
	out ACSR,temp			; set up analog comparator.
	out WDTCR,temp			; watchdog off
	out GIMSK,temp			; int0 off
	out WDTCR,temp			; Wdog off.
        ldi temp,1
        mov millisec,temp               ; 1mS
        mov ticks,temp                  ; 10 mS
        mov seconds,temp                ; 1 S
        mov ten_secs,temp               ; 10 S
        mov cw_interval,temp            ; we should get an almost immediate CWID

main:	cli				; master ints off
;
	ldi temp,0x02			; Set clock mode = /8
	out TCCR0,temp			;
;
	clr action			;
        ldi reload,TX_RELOAD
;
	ldi temp,(1<<TOIE0)
	out TIMSK,temp			; timer ints on.
;
        sei                             ; main ints ON.
;
; Fall into IDLE at startup
;
setup_idle:
;       Here so in idle mode.
        ldi flag_reg,FLAG_DATA
; monitor action bits
        mov temp,action
        andi temp,0x0f
        ori temp,0x40
        out PORTD,temp

idle_loop:
        cbi PORTB,PTTout                ; unassert PTTout line
        sbi PORTB,LEDout                ; - & LED off

; check for DCD from modem
        sbrc options,INVDCD             ; see which way up we are sensing DCD
        rjmp idle_20

        sbic PINB,DCDin                 ; See if anything out there...
        rjmp setup_busy                 ; here so goto busy code.
        rjmp idle_50

idle_20:
        sbis PINB,DCDin                 ; See if anything out there...
        rjmp setup_busy                 ; here so goto busy code.

idle_50:
; nowt so far so check if CWID is due yet
        sbrs action,CWID_SEND           ; if CW bit set skip
        rjmp idle_loop

        sbi PORTB,PTTout                ; assert PTTout line
        cbi PORTB,LEDout                ; - & LED on
        rcall do_cwid                   ; do the CWID shuffle
        rjmp idle_loop
;
setup_busy:
;       Here so keyed up
        sbi PORTB,PTTout                ; assert PTTout line

busy_loop:
;
; check for DCD from modem
        sbrc options,INVDCD             ; see which way up we are sensing DCD
        rjmp busy_20

        sbis PINB,DCDin                 ; skip if DCD still
        rjmp main                       ; go to idle
        rjmp busy_50

busy_20:
        sbic PINB,DCDin                 ; skip if DCD still
        rjmp main                       ; go to idle

busy_50:
; monitor action bits
        mov temp,action
        andi temp,0x0f
        ori temp,0x40
        out PORTD,temp
;
; nowt so far so check if CWID is due yet
        sbrc action,CWID_SEND           ; if CW bit clear skip
        rcall do_cwid

        sbrs action,SAMPLE              ; if sample bit set skip
        rjmp rx_extract_rx_clock        ; else go here
;
        cbr action,(1<<SAMPLE)          ; reset action bit

;================================================================
;       decide what sort of data to send - flags or real data
;================================================================

        sbrc options,ALLXFER            ; if always transfer bit set skip
        rjmp send_data

        sbrs action,XFER_FLAG           ; if transfer bit set skip
        rjmp send_flags                 ; else go here

; transfer real data - illuminate the LED!!
send_data:
        cbi PORTB,LEDout                ; LED on

        lsl txdat
        sbrc raw_rx,BIT0                ; skip if LSB of RXin in =0
        inc txdat                       ; else set LSB of data

        rjmp do_tx

; data is in NRZ but the modem want NRZI so we convert on the fly
send_flags:
        sbi PORTB,LEDout                ; LED off

        mov temp,txdat                  ; copy last bit TXed
; roll the flags bits for next time
        lsl flag_reg                    ; MSB to carry, LSB =0
        brcc flags_10                   ; if MSB was set then
        inc flag_reg                    ; - set LSB to make 8 bit rotate
flags_10:
        lsl txdat                       ; make room for new bit

        eor temp,flag_reg               ; compare with last TX bit
        sbrs temp,BIT0                  ; change in data leaves bit set
        inc txdat                       ; - no change means data = 1

do_tx:
        sbrs txdat,BIT0                 ; test data to create output
        cbi PORTB,TXout                 ; clear TX data
        sbrc txdat,BIT0                 ; test data to create output
        sbi PORTB,TXout                 ; set TX data

;================================================================
; read the data in from the port
;================================================================

        mov temp,raw_rx                 ; copy last bit RXed
        lsl raw_rx                      ; make room for new bit
        lsl rxdat                       ; - in raw & decoded registers

        sbic PINB,RXin                  ; skip if RXin in =0
        inc raw_rx                      ; else set LSB of data
        eor temp,raw_rx                 ; compare with last RX bit
        sbrs temp,BIT0                  ; change in data leaves bit set
        inc rxdat                       ; - no change means data = 1

;================================================================
;	Detect the presence of 8 all 1's or all 0's as this
;       is used to signify bad (ie. non-HDLC) data is being RXed
;================================================================

        tst raw_rx                      ; refresh Z bit.
        brne rx_3                       ; if all bits are 0's
;
;	Here so all bits are 0's.
;
        cbr action,(1<<XFER_FLAG)       ; reset data transfer bit
        rjmp busy_loop                  ; loop while in TX mode
;
rx_3:   cpi raw_rx,0xFF                 ; is it full of 1's
        brne rx_5                       ; no br
;
;	Here so all bits are 1's.
;
        cbr action,(1<<XFER_FLAG)       ; reset data transfer bit
        rjmp busy_loop                  ; loop while in TX mode
;
rx_5:
; neither all 0's or 1's so cwid off
; look for a flag byte if not already transfering

        sbrc action,XFER_FLAG           ; if transfer bit clear skip
        rjmp busy_loop                  ; loop while in TX mode

        cpi rxdat,FLAG_DATA             ; is the decoded data a flag
        brne rx_7                       ; no br

        sbr action,(1<<XFER_FLAG)       ; set data transfer bit

rx_7:
        rjmp busy_loop                  ; loop while in TX mode

;
;================================================================
;
rx_extract_rx_clock:
;
;	Check for HDLC input changing. We need this because we have to
;	extract a clock from the Tx data as well as the Rx data.
;	This is done with a 3 bit counter, when this code detects
;	the Tx data input has changed the counter is reset to 0
;	when the fast tx interrupt increments the counter from
;	03 to 04 the state of the tx input is sampled and the data
;	is then fed to the scrambler (back in the main loop).
;
        in pbnow,PINB                   ; read port B inputs
	mov temp,pbnow			; save it
        eor pbnow,pblast                ; has RXin changed
        andi pbnow,(1<<RXin)            ; 1 bit only
        breq rx_2                       ; no branch
;
        mov pblast,temp                 ; yes, so set last=now
        andi temp,(1<<RXin)             ; look for new TX being a 1
        breq rx_2                       ; skip adjust if 1 > 0 transition
        clr txpll                       ; hdlc input changed so reset pll counter
        ldi temp,-TX_RELOAD             ; ensure we are starting OK
        out TCNT0,temp                  ; zero the hardware as well
; this duplicates that in the interrupt code but we might miss that one when
; - we clear the txpll variable here!!
        sbrc options,INVRXC             ; if RX clocks to be inverted
        cbi PORTB,RXclock               ; data stable so CLEAR T(R)Xclock
        sbrs options,INVRXC             ; if RX clocks to be inverted
        sbi PORTB,RXclock               ; Time for new TX data so set T(R)Xclock
;
rx_2:   rjmp busy_loop                  ; loop while in TX mode



;==================================================================
; delay .5 second - interrupts off - screws up timer setup
;==================================================================

delay_5s:
        clr temp
        out TCNT0,temp                  ; count = 256
        out TIMSK,temp                  ; timer ints off.
        ldi temp,0x05                   ; Set clock mode = /1024
	out TCCR0,temp			;
        ldi delay,17                    ; number of times round the loop

del_30:
        in temp,TIFR
        andi temp,(1<<TOV0)
        breq del_30

        ldi temp,(1<<TOV0)
        out TIFR,temp                   ; clear the overflow bit
        dec delay                       ; actually 37.5 per sec
        brne del_30

        ret


;==================================================================
; write value in temp to EEPROM, increment address
;==================================================================

write_ee:
        out EEDR,temp                   ; set eeprom data
        sbi EECR,EEWE                   ; write eeprom.
ee_30:
        sbic EECR,EEWE                  ; poll write bit, skip when done
        rjmp ee_30

        in temp,EEAR                    ; get eeprom address
        inc temp
        out EEAR,temp                   ; set up next eeprom address
        ret


;==================================================================
; output the CWID as a series of mark/spaces in the correct ratio!!
; inner loop = bits in a character, outer loop = chars
;==================================================================
do_cwid:
        sbrc options,NOCWID     ; if CWID enabled skip
        rjmp cwid_ex            ; else exit

        ldi temp,0              ; offset into eeprom
        out EEAR,temp           ; set up eeprom read address
cwid_10:
        sbi EECR,EERE           ; read eeprom command
        in temp,EEDR            ; read eeprom data
        tst temp
        breq cwid_ex            ; zero data = completed
        cpi temp,0xff           ; space
        breq cwid_90
        mov cwid_dat,temp       ; dot/dash bit pattern
cwid_30:
        sbrs cwid_dat,BIT0      ; see if dot or dash
        rjmp cwid_40

        ldi temp,(120 / CWID_WPM) * 3   ; dash = 3 dits
        mov ditclock,temp
        rjmp cwid_50
cwid_40:
        ldi temp,120 / CWID_WPM         ; dot = 1 dit
        mov ditclock,temp

cwid_50:
        cbr action,(1<<CWID_DIT)        ; reset dit complete bit
        sbrc options,INVCWID            ; if CWID to be inverted?
        sbi PORTB,TXout                 ; put TX data on
        sbrs options,INVCWID            ; skip if invert
        cbi PORTB,TXout                 ; put TX data off
cwid_60:
        sbrs action,CWID_DIT
        rjmp cwid_60                    ; wait for dit to complete

        ldi temp,120 / CWID_WPM         ; inter dit = 1 dit
        mov ditclock,temp
        cbr action,(1<<CWID_DIT)        ; reset dit complete bit
        sbrc options,INVCWID            ; if CWID to be inverted?
        cbi PORTB,TXout                 ; put TX data off
        sbrs options,INVCWID            ; if CWID to be inverted?
        sbi PORTB,TXout                 ; put TX data off
cwid_70:
        sbrs action,CWID_DIT
        rjmp cwid_70                    ; wait for gap to complete

        lsr cwid_dat                    ; shift the data down one
        cpi cwid_dat,0b000001
        brne cwid_30

; complete this character - 3 dits delay then get another
        ldi temp,(120 / CWID_WPM) * 3   ; inter char = 3 dit
        mov ditclock,temp
        cbr action,(1<<CWID_DIT)        ; reset dit complete bit
cwid_80:
        sbrs action,CWID_DIT
        rjmp cwid_80                    ; wait for gap to complete
        rjmp cwid_95

cwid_90:
        ldi temp,(120 / CWID_WPM) * 5   ; space = 5 dit
        mov ditclock,temp
        cbr action,(1<<CWID_DIT)        ; reset dit complete bit
cwid_93:
        sbrs action,CWID_DIT
        rjmp cwid_93                    ; wait for gap to complete

cwid_95:
        in temp,EEAR                    ; get eeprom address
        inc temp
        out EEAR,temp                   ; set up next eeprom address
        rjmp cwid_10

cwid_ex:
        cbr action,(1<<CWID_SEND)       ; reset action bit
        ret


;==================================================================
;	Timer overflow interrupt. Called by Vector.
;==================================================================
;
TIMER_int:
;
	in irq_sreg,SREG		; save SREG
	mov irq_temp,temp		; and temp
;
;
;====================================================================
;       Called by TCNT0 overflow interrupt 8 x baudrate (13.02us@9600Bd)
;====================================================================
;
	in temp,TCNT0			; read TCNT0
        sub temp,reload                 ; this may be adjusted by the DPLL
        out TCNT0,temp                  ; replace it
        ldi reload,TX_RELOAD            ; remaining 7 clocks stay as is
;
;
; one data bit further on!!
        dec millisec
        brne tt_pll

; completed .5mS (approx) - this is a sort of prescaler, now count a tick
        ldi temp,48
        mov millisec,temp
        dec ticks
        brne tt_pll

; completed a tick, try for a 1 second
        ldi temp,153600/BAUD            ; 9k6 =16; 1k2 =128
        mov ticks,temp                  ; reset tick to 10mS

        in temp,PORTD
        ldi temp1,0b00010000
        eor temp,temp1
        out PORTD,temp                  ; see if we toggle every 10mS

; if we are sending a CWID then look to see if we have completed the
; current dot or dash

        sbrs action,CWID_SEND           ; if CW bit set skip
        rjmp not_dit

        dec ditclock
        brne not_dit
        sbr action,(1<<CWID_DIT)        ; signal dot/dash completed

not_dit:
        dec seconds
        brne tt_pll

; completed 1 second, try for 10
        ldi temp,100
        mov seconds,temp
        in temp,PORTD
        ldi temp1,0b00100000
        eor temp,temp1
        out PORTD,temp
        dec ten_secs
        brne tt_pll

; completed 10 seconds, test CWID interval
        ldi temp,10
        mov ten_secs,temp
        dec cw_interval
        brne tt_pll

; completed 10 secs - look at the CWID interval
        ldi temp,CWID_TIME/10
        mov cw_interval,temp
        sbr action,(1<<CWID_SEND)       ; send a CWID ASAP

tt_pll:
;       Extract a clock from TX HDLC data.
;	In external TX clock mode, the rising edge clocks out TX data to us
;	We therefore generate that and then drop the clock and sample the data
;	4 interrupts later (half way through the bit).
;	
        inc txpll                       ; txpll++;
	andi txpll,0x07			; 3 bits only
        brne tt_pll_1                   ; == 0 ? no br

        sbrc options,INVRXC             ; if RX clocks to be inverted
        cbi PORTB,RXclock               ; Time for new TX data so set T(R)Xclock
        sbrs options,INVRXC             ; if RX clocks to be inverted
        sbi PORTB,RXclock               ; Time for new TX data so set T(R)Xclock
                ; this bit may not get set reliably here since txpll
                ; gets cleared in the main loop - it gets set there as well!

;
tt_pll_1:
        cpi txpll,4                     ; 'halfway through bit' == 4 ?
	brne tt_out			; no branch
;
        sbrs options,INVRXC             ; if RX clocks to be inverted
        cbi PORTB,RXclock               ; data stable so CLEAR RXclock
        sbrc options,INVRXC             ; if RX clocks to be inverted
        sbi PORTB,RXclock               ; data stable so SET RXclock
        sbr action,(1<<SAMPLE)          ; sample HDLC input.
;
tt_out:
;
        mov temp,irq_temp               ; recover temp
	out SREG,irq_sreg		; recover sreg.
	reti				; return
;